The aim of this unit is to provide you with a solid understanding of string manipulation using Reference Modification. It will also introduce you to Intrinsic Functions and will show how strings may be manipulated using the String Intrinsic Functions.

By the end of this unit you should:

1. Understand how Reference Modification works
2. Be able to use Reference Modification to extract and insert sub-strings.
3. Understand how Intrinsic Functions work.
4. Be able to using Intrinsic Functions for string and date manipulation.

Reference Modification allows you to treat a numeric (PIC 9) or alphanumeric (PIC X) data-item as if it were an array of characters. To access sub-strings using Reference Modification you must specify;

• the name of the data-item
• the start character position of the sub-string
• the number of characters in the sub-string

To apply Reference Modification the following syntax must be used.

DataName(StartPos [:SubStrLength])

StartPos is the character position of the first character in the sub-string and SubStrLength is number of characters in the substring.

As the square brackets indicate, the SubStrLength may be omitted, and in that case the substring from StartPos to the end of the string is assumed.

Reference Modification may be used almost anywhere an alphanumeric data-item is permitted.

WORKING-STORAGE SECTION.
01 xString    PIC X(38) VALUE "This is the alphanumeric string".
01 nString    PIC 9(5)V99 VALUE 34526.56.
01 SubStrSize PIC 99 VALUE 12.
01 StartPos   PIC 99 VALUE 18.

Although COBOL does not permit user-defined functions or procedures, it does have a number of Intrinsic (built-in) Functions, which you can use in your programs.

These functions fall into three broad categories : date functions, numeric functions and string functions.

Like functions in other languages, an Intrinsic Function is replaced in the position where it occurs by the function result.

In COBOL, an Intrinsic Function is a temporary data item whose value is determined at the time the function is executed.

Wherever a literal with the same type as the function result may be referenced, the Intrinsic Function may be referenced.

• Where the function result is alphanumeric it has an implicit usage of DISPLAY.
• Functions that return a number value (numeric & integer) are always considered to be signed.
• A function that returns a number value can be used only in an arithmetic expression or as the source of a MOVE statement.
• A function that returns a numeric value cannot be used where an integer operand is required (because it may return a non-integer value).

An Intrinsic Function consists of three parts;

1. The start of the function is signalled by the keyword - FUNCTION.
2. The keyword is followed by the name of the function.
3. The name of the function is immediately followed by the bracketed list of parameters or arguments.

The template for Intrinsic Functions is shown below:

FUNCTION FunctionName(Parameters)

FunctionName is the name of the function and Parameters is one or more parameters supplied to the function.

Example declarations.

MOVE FUNCTION RANDOM(99) TO RandNum. 

DISPLAY FUNCTION UPPER-CASE("this will be in upper case").

In the Intrinsic Function definitions in the sections below the functions produce a result of one of the following types;

• Alphanumeric
• Numeric (includes Integer)
• Integer (does not allow the decimal point)

Where parameters are required in the function the parameter name is used to indicate the type of the parameter.

• Alph indicates Alphanumeric
• Num indicates any Numeric
• PosNum indicates a Positive Numeric
• Int indicates any Integer
• PosInt indicates a PositiveInteger
• Any indicates that any type may be used

Where a function takes a parameter list (indicated by {Any}... in the function definition) the parameter list may be replaced by an array. The reserved word ALL is used as the array subscript to indicate all the elements of the array.

For instance the ORD-MAX function may take a parameter list or an array may be used:

MOVE FUNCTION ORD-MAX(12 23 03 78 65) TO OrdPos
                     or
MOVE FUNCTION ORD-MAX(IntElement(ALL)) TO OrdPos             

The statements in the following examples produce the results shown below.

IDENTIFICATION DIVISION.
PROGRAM-ID. StringFunctions.
AUTHOR. Michael Coughlan.
DATA DIVISION.
WORKING-STORAGE SECTION.
01 xString PIC X(38) VALUE "This is the alphanumeric string".
01 OrdPos PIC 99.
01 IntArray VALUE "1223037865".
   02 Ielement OCCURS 5 TIMES PIC 99.

PROCEDURE DIVISION.
Begin.
  DISPLAY "Character at pos 39 is = " FUNCTION CHAR(39)

  MOVE FUNCTION ORD("A") TO OrdPos
  DISPLAY "Ord pos of A is = " OrdPos

  MOVE FUNCTION ORD-MAX("t" "b" "x" "s") TO OrdPos
  DISPLAY "Highest character in sequence is at pos " OrdPos

  MOVE FUNCTION ORD-MIN("t" "b" "x" "s") TO OrdPos
  DISPLAY "Lowest character in sequence is at pos " OrdPos

  MOVE FUNCTION ORD-MAX(Ielement(ALL)) TO OrdPos
  DISPLAY "Number " Ielement(OrdPos) " is the highest in array".

  DISPLAY "Length of xString is " FUNCTION LENGTH(xString)
  DISPLAY FUNCTION REVERSE(xString(1:31))
  DISPLAY FUNCTION UPPER-CASE(xString)
  DISPLAY FUNCTION LOWER-CASE(xString)
  STOP RUN.

The example program below uses most of the date functions described in the table above. The results from running the program are shown below.

IDENTIFICATION DIVISION.
PROGRAM-ID. DateFunctions.
AUTHOR. Michael Coughlan.
DATA DIVISION.
WORKING-STORAGE SECTION.
01 DateAndTimeC.
   02 DateC.
      03 YearC    PIC 9(4).
      03 MonthC   PIC 99.
      03 DayC     PIC 99.
   02 TimeC.
      03 HourC    PIC 99.
      03 MinC     PIC 99.
      03 SecC     PIC 99.
      03 HundredC PIC 99.
   02 GMT.
      03 GMTDiff  PIC X.
         88 GMTNotSupported VALUE "0".
      03 GMTHours PIC 99.
      03 GMTMins  PIC 99.
01 BillDate       PIC 9(8).
01 DateNow        PIC 9(8).
01 DaysOverdue    PIC S999.
01 NumOfDays      PIC 999.
01 IntFutureDate  PIC 9(8).
01 FutureDate     PIC 9(8).
01 DisplayDate REDEFINES FutureDate.
   02 YearD       PIC 9999.
   02 MonthD      PIC 99.
   02 DayD        PIC 99.

PROCEDURE DIVISION.
Begin.
*> This example gets the current date and displays
*> its constituent parts.
  MOVE FUNCTION CURRENT-DATE TO DateAndTimeC
  DISPLAY "Current Date is " MonthC "/" DayC "/" YearC
  DISPLAY "Current Time is " HourC ":" MinC ":" SecC
  IF GMTNotSupported
     DISPLAY "This computer cannot supply the time"
     DISPLAY "difference between local and GMT."
   ELSE
     DISPLAY "The local time is - GMT "
              GMTDiff GMTHours ":" GMTMins
  END-IF.

*> In this example bills fall due 30 days from
*> the billing date.
  DISPLAY "Enter the date of the bill (yyyymmdd) "
           WITH NO ADVANCING
  ACCEPT BillDate
  MOVE DateC TO DateNow
  COMPUTE DaysOverDue = (FUNCTION INTEGER-OF-DATE(DateNow))
                      - (FUNCTION INTEGER-OF-DATE(BillDate)+ 30)
  EVALUATE TRUE
    WHEN DaysOverDue > ZERO DISPLAY "This bill is over due"
    WHEN DaysOverDue = ZERO DISPLAY "This bill is due today"
    WHEN DaysOverDue < ZERO DISPLAY "This bill is not yet due"
  END-EVALUATE

*> This example displays the date NumOfDays days
*> from the current date
  DISPLAY "Enter the number of days - "
  WITH NO ADVANCING
  ACCEPT NumOfDays
  COMPUTE IntFutureDate =
  FUNCTION INTEGER-OF-DATE(DateNow)+ NumOfDays + 1
  MOVE FUNCTION DATE-OF-INTEGER(IntFutureDate) TO FutureDate
  DISPLAY "The date in "
  NumOfDays " days time will be " MonthD "/" DayD "/" YearD
  STOP RUN.

The example program below uses many of the functions described in the table above. The results from running the program are shown below.

IDENTIFICATION DIVISION.
PROGRAM-ID.  OtherFunctions.
AUTHOR.  Michael Coughlan.
*> An example program using misc Intrinsic Functions

DATA DIVISION.
WORKING-STORAGE SECTION.
01  IntParameters.
    02 IP1          PIC 99   VALUE 25.
    02 IP2          PIC 99   VALUE 50.
    02 IP3          PIC 9(5) VALUE 12.
    02 IResult      PIC 9(5).

01  NumResult       PIC 9.9(5).

01 IntArray VALUE "1223037865".
   02 Ielement OCCURS 5 TIMES PIC 99.

PROCEDURE DIVISION.
Begin.
  MOVE FUNCTION MAX(IP1 545 IP3 IP2) TO IResult
  DISPLAY "Max value is = " IResult

  MOVE FUNCTION MAX(Ielement(ALL)) TO IResult
  DISPLAY "Max value is = " IResult

  MOVE FUNCTION MEDIAN(Ielement(ALL)) TO IResult
  DISPLAY "Median value is = " IResult

  MOVE FUNCTION MIDRANGE(Ielement(ALL)) TO IResult
  DISPLAY "Midrange value is = " IResult

  MOVE FUNCTION MIN(Ielement(ALL)) TO IResult
  DISPLAY "Min value is = " IResult

  MOVE FUNCTION RANGE(Ielement(ALL)) TO IResult
  DISPLAY "Range is " IResult

  MOVE FUNCTION SUM(Ielement(ALL)) TO IResult
  DISPLAY "The sum of the values is " IResult

  MOVE FUNCTION VARIANCE(Ielement(ALL)) TO IResult
  DISPLAY "The variance of the values is " IResult
  STOP RUN.

The example program below uses the RANDOM function to get and display 6 unique lotto numbers. Valid lotto numbers fall between 1 and 42.

In this program the last five digits of the system time (i.e. minutes, seconds and hundredths of seconds) is used as the random number seed.

The algorithm is based on Niklaus Wirth's algorithm for finding a set of unique integers. In this algorithm when the loop test in executed -

i + 1 is the position where the current number was inserted
j is the first position where the current number was found
If i + 1 = j then the current number has no duplicates.

IDENTIFICATION DIVISION.
PROGRAM-ID.  Lotto.
AUTHOR.  Michael Coughlan.
*> This program displays six unique random lotto numbers.
*> It was Adapted from a program written by Dermot Shinners-Kennedy

DATA DIVISION.
WORKING-STORAGE SECTION.
01 LottoNum  PIC 9(5) OCCURS 6 TIMES INDEXED BY j.
01 i         PIC 9(3).
01 RandNum   PIC 9(3).
01 SysDate.
   02 FILLER PIC 9(11).
   02 Seed   PIC 9(5).

PROCEDURE DIVISION.
Begin.
   MOVE FUNCTION CURRENT-DATE TO SysDate
   COMPUTE RandNum = FUNCTION RANDOM(Seed)

   SET i to ZERO
   PERFORM 6 TIMES
      PERFORM WITH TEST AFTER UNTIL i + 1 = j
        COMPUTE LottoNum(i + 1), RandNum =
                (FUNCTION RANDOM * 42) + 1
        SET j to 1
        SEARCH LottoNum
           WHEN LottoNum(j) = RandNum CONTINUE
        END-SEARCH
      END-PERFORM
      ADD 1 to i
      DISPLAY LottoNum(i) SPACE WITH NO ADVANCING
   END-PERFORM
   STOP RUN.